;--------------------------------;
; Pinkston Delay Instruments 2-3 ;
;--------------------------------;

sr	=	22050
kr	=	2205
ksmps	=	10.0
nchnls	=	2

	instr	2		;dry pluck
gasend	init	0		;init global "send"
kgate	linseg	p4,.1,0,1,0	;.1 second ramp
icps	=	cpspch(p5)	;p5 in pch
asig	pluck	kgate,icps,icps,0,1,0,0	;simple pluck
	outs	asig,asig	;straight out
gasend	=	gasend+asig	;add to global var
	endin		
;------------- A global effect instrument -----------------;			
	instr	3		;stereo echoes
atap1	delay	gasend*p4,p6	;use global var
atap2	delay	gasend*p5,p7	;for inputs
	outs	atap1,atap2	;stereo echoes
gasend	=	0		;clear global var
	endin			
	

;Sample Score for Pinkston Delay Chapter Instruments 2-3
;Play a short 2-part harmony; note durs = pluck durs
;	st	dur	amp	pch		
i2	0	.1	15000	7.00		
i2	0	.	.	7.04		
i2	1	.	.	7.07		
i2	1	.	.	8.05		
i2	1.5	.	.	8.04		
i2	1.5	.	.	8.00		
i2	2	.	.	8.10		
i2	2	.	.	9.02		
;Global delay instr is on for entire passage + longest echo
;	st	dur	fac1	fac2	echo1	echo2
i3	0	2.5	.7	.5	.15	.4
e